コンソール表示・入力ルーチン後編

戻る


　今回は、前回説明した低レベルルーチンを呼び出す、上位のルーチン群を解説します。

・CRLF／SPACE

　それぞれ改行／空白を表示するルーチンです。

CRLF:	STS.L	PR,@-R15	; ＰＲ保存
	BSR	PUTCH		; 　　↓を１文字表示
	MOV	#H'0D,R0	; ＣＲコード（遅延スロット）

	LDS.L	@R15+,PR	; ＰＲ復帰
	BRA	PUTCH		; 　　↓を１文字表示
	MOV	#H'0A,R0	; ＬＦコード（遅延スロット）

SPACE:	BRA	PUTCH		; 　　↓を１文字表示
	MOV	#H'20,R0	; 空白（遅延スロット）

　説明の必要も無いほど簡単なルーチンですが、使用頻度は結構高く、ありがたいルーチンです。

・PUTSTR

　Ｃ言語で言うところの PUTS()　に該当するルーチンです。０で終わる、Ｃ言語風文字列を表示します。文字列の先頭番地をＲ２に入れて呼びだします。
（ちなみに先頭に長さデータが付いているのが PASCAL風文字列です。なんだかんだ言って、Ｃ言語風文字列の方が扱いは楽なんですよね。PASCAL風だと、こういうとき長さをカウントするためにもう一つ汎用レジスタが必要になってしまいます。）

PUTSTR:	MOV.B	@R2+,R0		; 最初の文字を読む
	STS.L	PR,@-R15	; ＰＲ保存

PUTSTRL:CMP/EQ	#0,R0		; ０（文字列の終わり）か？
	BT	PUTSTE		; 終わりなら終了処理へ
	BSR	PUTCH		; その文字を出力
	NOP			; （遅延スロット）

	BRA	PUTSTRL		; ループ繰り返し
	MOV.B	@R2+,R0		; 次の文字を読む（遅延スロット）

PUTSTE:	LDS.L	@R15+,PR	; ＰＲ復帰
	RTS			; リターン
	NOP			; （遅延スロット）

　まずＲ２が指す最初の文字を読んでからＰＲを保存しています。これは次の CMP/EQ でのパイプラインストールを少しでも減らすためです。
　読んだ値が０なら文字列の終わりなのでループを抜けます。そうでなければその文字を表示します。BSR の遅延スロットに何も入れられないのがつくづく残念です。
　次の BRA の遅延スロットにはメモリを読む MOV 命令を入れています。パイプラインストールの軽減にはならないのですが、NOP を入れるよりましでしょう。
　最後はお約束的にＰＲを復帰してリターンします。

・DOT／UDOT

　符号付き／符号無し１０進左詰表示ルーチンです。Ｒ２の値を表示します。名前の由来ですが、ずっと昔に作ったＭＳＸ用ＦＯＲＴＨのルーチン名を引きずっています。ＦＯＲＴＨでは数値表示するワードは "." です。だから「ドット」なんですね。それがＭＳＸ用超ミニＢＡＳＩＣを作ったときにそのサブルーチンが使いまわしされ、他のＣＰＵに移植した際にもルーチン名だけはそのまま残ってます。

DOT:	MOV.L	R3,@-R15	; Ｒ３保存
	MOV.L	ITOABF1,R3	; 変換用バッファの番地
	STS.L	PR,@-R15	; ＰＲ保存
	BSR	ITOA		; ITOA 呼びだし
	NOP			; （遅延スロット）

　開始部分です。１０進変換するために第２回で説明した ITOA を使っています。Ｒ３は ITOA でも壊されるので保存します。また、このルーチンは末端ルーチンではないので当然ですがＰＲも保存します。
　ITOABF というのは、１０進変換後のアスキーコード文字列を格納するワークエリアです。ITOA を呼びだすと、Ｒ２の値が１０進変換され、Ｒ３が指す ITOABF に格納されます。

	MOV.L	ITOABF1,R2	; バッファの番地（変換済みデータが格納されている）
	BSR	PUTCH		; 最初の１文字（符号）を表示
	MOV.B	@R2+,R0		; 変換後の最初の１文字を読む（遅延スロット）

	BRA	UDOT1		; UDOT1 へ飛ぶ
	NOP			; （遅延スロット）

　ITOA によって変換された最初の番地には数値の符号が入っています。正の数なら空白、負の数なら '-' です。それを読みだして出力します。その後、DOT と UDOT の共通処理 UDOT1 へ飛びます。

UDOT:	MOV.L	R3,@-R15	; Ｒ３保存
	MOV.L	ITOABF1,R3	; 変換用バッファの番地
	STS.L	PR,@-R15	; ＰＲ保存
	BSR	UITOA		; UITOA 呼びだし
	NOP			; （遅延スロット）

	MOV.L	ITOABF1,R2	; バッファの番地（変換済みデータが格納されている）

　UDOT の開始部分です。こちらは符号無し変換ルーチン UITOA を使います。また最初の符号出力はしません。

UDOT1:	MOV.B	@R2+,R0		; １文字読む
	CMP/EQ	#0,R0		; 文字列の終わりか？
	BT	UDOTE		; 文字列の終わりなら終了
	CMP/EQ	#H'20,R0	; 空白か？
	BT	UDOT1		; 空白ならループ繰り返し
	BSR	PUTSTR		; PUTSTR 呼びだし
	ADD	#-1,R2		; １文字進みすぎているので戻す（遅延スロット）

　共通処理です。ITOA／UITOA は右詰出力なので、頭の余分な空白を無視する必要があります。残念ながら文字列を指してるポインタがＲ２なので SKIPSP は使えません。また、このくらいの小さなループだとサブルーチン呼ぶよりその場に書いてしまったほうが簡単だったりするのでここでループしています。
　空白を飛ばした後、 PUTSTR を呼びだします。ITOA／UITOA は文字列の末尾に０を付加するので PUTSTR で出力できます。ITOABF を指すのにＲ３ではなくＲ２を使った理由は、PUTSTR のパラメータはＲ２で渡すからです。

UDOTE:	LDS.L	@R15+,PR	; ＰＲ復帰
	RTS			; リターン
	MOV.L	@R15+,R3	; Ｒ３復帰（遅延スロット）

　終了処理です。ＰＲとＲ３を復帰してリターンします。

・UDOTR

　Ｒ２の値を符号無し右詰め表示するルーチンです。ＬＩＳＴコマンドの行番号表示で使われます。

UDOTR:	MOV.L	R3,@-R15	; Ｒ３保存
	MOV.L	ITOABF1,R3	; 変換用バッファの番地
	STS.L	PR,@-R15	; ＰＲ保存
	BSR	UITOA		; UITOA 呼びだし
	NOP			; （遅延スロット）

	MOV.L	ITOABF1,R2	; 変換後の文字列を
	BSR	PUTSTR		; そのまま PUTSTR で出力
	NOP			; （遅延スロット）

	LDS.L	@R15+,PR	; ＰＲ復帰
	RTS			; リターン
	MOV.L	@R15+,R3	; Ｒ３復帰（遅延スロット）

　DOT／UDOT と違い、空白除去がありません。UITOA の右詰出力結果をそのまま表示します。特に説明はいらないでしょう。

・GETLN

　行入力ルーチンです。コマンド、プログラムの入力や、ＩＮＰＵＴ文で使われます。一行ぶんの入力を行い、ワークエリア LINBUF にその内容を返します。ＥＮＴＥＲキーが押されて正常終了した場合はＴビット＝１でリターンします。ＣＴＲＬ−Ｃで入力が中断された場合はＴビット＝０でリターンします。

　ＩＮＰＵＴ文がダイレクトモードで使えない仕様になっているのは、ここに理由があります。ダイレクトモードでは LINBUF に入力された文字列を解釈・実行しているわけですが、 LINBUF は１つしかないので、ＩＮＰＵＴ文の入力で LINBUF が上書きされると、今まさに実行している文字列が消えてしまいます。わざわざＩＮＰＵＴ文のダイレクト実行のためだけに２５６バイト近いサイズのバッファをもう１つ確保するのもバカバカしいので（そもそも変数に数値を入れたいなら代入すればよい）、ダイレクトモードではＩＮＰＵＴ文は使えない仕様にしました。



GETLN:	MOV.L	R4,@-R15		; Ｒ４保存
	MOV.L	R5,@-R15		; Ｒ５保存
	STS.L	PR,@-R15		; ＰＲ保存
	MOV	#0,R3			; 長さの初期値＝０
	MOV	R3,R0			; ついでにその０で
	MOV.B	R0,@(LATKEY-WRKTOP,GBR)	; LATKEYもクリヤする
	MOV.L	LINBUF1,R4		; 入力用バッファの先頭番地
	MOV	#MAXLL,R5		; 最大入力可能文字数＝２４０

　開始部分です。レジスタの保存を行い、LATKEY をクリヤします。このルーチンを実行中は、Ｒ４は文字の格納先の番地を指しており、またＲ３は入力された文字数を表しています。最初は何も入力されていないので、Ｒ３＝０、Ｒ４は文字列格納領域の先頭番地 LINBUF です。Ｒ５には入力可能な最大文字数を入れておきます。

　って、Ｒ５を EXTU.B しなきゃダメじゃん・・・Ｈ８じゃないんだから。あ、本編ＣＭＢも EXTU やってない・・・orz　ああ、自己嫌悪。

GETLNL:	BSR	GETCH		; １文字入力する
	NOP			; （遅延スロット）

	CMP/EQ	#H'03,R0	; ＣＴＲＬ−Ｃなら
	BT	GETLNN		; 　　行入力キャンセル
	CMP/EQ	#H'0D,R0	; ＥＮＴＥＲキーなら
	BT	GETLNE		; 　　行入力正常終了
	CMP/EQ	#H'08,R0	; ＢＳキーなら
	BT	GETLBS		; 　　ＢＳ処理へ
	CMP/EQ	#H'09,R0	; ＴＡＢキー以外の文字なら
	BF	GETLN1		; 　　GETLN1 へ
	MOV	#H'20,R0	; ＴＡＢは空白に置きかえる
GETLN1:	MOV	#H'20,R13	; 文字コードが
	CMP/HS	R13,R0		; 　　H'20未満なら
	BF	GETLNL		; 　　　　その文字は無視
	CMP/HS	R5,R3		; 最大入力可能文字数に達していたら
	BT	GETLNL		; 　　それ以上入力しない
	BSR	PUTCH		; 入力された文字を表示
	MOV.B	R0,@R4		; その文字をバッファに置く（遅延スロット）

	ADD	#1,R3		; 文字数をインクリメント
	BRA	GETLNL		; ループ繰り返し
	ADD	#1,R4		; バッファの書きこみポインタをインクリメント

　ループ部分です。１文字入力し、そのキーコードによって処理を振り分けます。入力可能な文字ならバッファに格納し、ＥＮＴＥＲ、ＢＳなどの機能キーならそれぞれの処理に分岐します。入力できない文字は無視します。
　最大文字数以上入力できないようにしていたつもりですが、Ｒ５を EXTU していないのでこのチェックは引っかかりません。まさかこんなところに今トレンディーな「バッファオーバーフロー脆弱性」が潜んでいようとは・・・orz

　まあ、不幸中の幸いというか、LINBUF はＲＡＭ領域のほぼ末尾に位置しており、その後ろには有効なワークエリアはありません。どんどん書き進んでいってもアドレスが０になってＲＯＭ領域に突入すると、もう当分は何も書きこめません。もしこのバッファオーバーフロー脆弱性を利用して悪さをするつもりならＩ／Ｏ領域やＲＡＭ領域にたどりつくまで約４Ｇバイトも文字を送り続ける必要があります



;（正常終了処理）
GETLNE:	BSR	CRLF		; 改行する
	NOP			; （遅延スロット）
	BRA	GETLNEE		; 共通終了処理へ
	CLRT			; Ｔビットをセット（遅延スロット）

;（キャンセル終了処理）
GETLNN:	BSR	CRLF		; 改行する
	NOP			; （遅延スロット）

	SETT			; Ｔビットをクリヤ

GETLNEE:MOV	#0,R0		; 行末に０を置く
	MOV.B	R0,@R4		; 
	MOV.B	R0,@(LATKEY-WRKTOP,GBR)	; ついでにLATKEY もクリヤ
	LDS.L	@R15+,PR	; ＰＲ復帰
	MOV.L	@R15+,R5	; Ｒ５復帰
	MOV.L	@R15+,R4	; Ｒ４復帰
	RTS			; リターン
	MOV.B	R0,@(LATKTM-WRKTOP,GBR)	; LATKTM もクリヤ（遅延スロット）

　終了処理です。ＥＮＴＥＲとＣＴＲＬ−Ｃの違いはＳＲのＴビットのセット／リセットだけで、ＣＴＲＬ−Ｃの場合でも行末に０を置きます。呼びだし元のルーチンは、GETLN 呼びだし後に LINBUF の先頭から、０が見つかるまでの文字列を処理すれば良いのです。

;（ＢＳキー処理）
GETLBS:	TST	R3,R3		; 現在入力されている文字が無ければ
	BT	GETLNL		; 　　ループに戻る
	BSR	PUTCH		; ＢＳを出力してカーソルを戻す
	MOV	#H'08,R0	; ＢＳコード（遅延スロット）

	BSR	PUTCH		; 空白を出力して前の１文字を消す
	MOV	#H'20,R0	; 空白のコード（遅延スロット）

	BSR	PUTCH		; もう一度ＢＳを出力してカーソルを戻す
	MOV	#H'08,R0	; ＢＳコード（遅延スロット）

	ADD	#-1,R3		; 文字数を１減らす
	BRA	GETLNL		; ループに戻る
	ADD	#-1,R4		; 書きこみポインタを１つ戻す（遅延スロット）

　ここはＢＳキーが押されたときの処理です。ほとんどのターミナルソフトはＢＳコードを送ってもカーソルが戻るだけで文字を消してはくれないのでさらに空白を送って再度ＢＳコードを送ります。文字数カウントや書きこみポインタも１文字ぶん戻します。

番外編　PUTXグループ

　１６進表示するルーチン群です。これらはＣＣＭＢには含まれていない、ＣＭＢのルーチンなのですが、「表示ルーチンのソースを載せるならこれを載せないでどうする」という重要なルーチンです。実際オールアセンブラのプログラムをデバッグする際には１０進より１６進数の表示のほうが圧倒的にニーズが高いです。さほど難しくは無いので詳細な説明はしませんが、各自読解してみてください。

;（Ｒ２を１６進８桁出力）
PUTX8:	STS.L	PR,@-R15	; ＰＲ保存
	MOV.L	R2,@-R15	; Ｒ２保存
	BSR	PUTX4		; 　　↓で移動した上位１６ビットを出力
	SHLR16	R2		; 上位１６ビットを下位へ移動（遅延スロット）

	BSR	PUTX4		; 　　↓で復帰したＲ２の下位１６ビットを出力
	MOV.L	@R15+,R2	; Ｒ２復帰（遅延スロット）

	LDS.L	@R15+,PR	; ＰＲ復帰
	RTS			; リターン
	NOP			; （遅延スロット）

;（Ｒ２の下位１６ビットを１６進４桁出力）
PUTX4:	STS.L	PR,@-R15	; ＰＲ復帰
	MOV	R2,R0		; Ｒ２をＲ０にコピー
	BSR	PUTX2		; 　　↓で移動したビット15〜8を出力
	SHLR8	R0		; ビット15〜8をビット7〜0に移動（遅延スロット）

	BSR	PUTX2		; 　　↓でコピーしたビット7〜0を出力
	MOV	R2,R0		; もう一度Ｒ２をＲ０にコピー（遅延スロット）

	LDS.L	@R15+,PR	; 以下、お約束
	RTS
	NOP 

;（Ｒ０の下位８ビットを１６進２桁出力）
PUTX2:	STS.L	PR,@-R15	; ＰＲ保存
	MOV.L	R0,@-R15	; Ｒ０保存
	SHLR2	R0		; ビット7〜4をビット5〜2に移動
	BSR	PUTX1		; 　　↓で移動した最初のビット7〜4を表示
	SHLR2	R0		; 最初のビット7〜4をビット3〜0に移動（遅延スロット）

	BSR	PUTX1		; 　　↓で復帰したＲ０のビット3〜0を表示
	MOV.L	@R15+,R0	; Ｒ０復帰（遅延スロット）

	LDS.L	@R15+,PR	; 以下お約束
	RTS 
	NOP

;（Ｒ０のビット3〜0を１６進１桁出力）
PUTX1:	AND	#H'0F,R0	; ビット3〜0のみ取りだす
	MOV	#H'0A,R13	; １０より
	CMP/HS	R13,R0		; 　　小さく
	BF	PUTX11		; 　　　　なければ
	ADD	#H'07,R0	; 　　　　　　７を足す
PUTX11:	BRA	PUTCH		; １文字出力（BRAなのでＰＲ保存不用）
	ADD	#H'30,R0	; H'30を足す（遅延スロット）


超番外編　Ｈ８版 PUTXグループ

　ソースの見た目のインパクトはＳＨ版より上です。ＰＲを保存しなくてよいＨ８は、ＳＨよりトリッキーなコードが書けます。

;（８桁出力）
PUTX8	PUSH.W	R2		; ＥＲ２の下位１６ビット保存
	MOV.W	E2,R2		; 上位１６ビットを下位へ移動
	BSR	PUTX4:8		; 移動した上位１６ビットを出力
	POP.W	R2		; 下位１６ビットを復帰し、
				; そのままPUTX4 になだれこんで下位１６ビットを表示
;（４桁出力）
PUTX4	MOV.B	R2H,R0L		; Ｒ２のビット15〜8をＲ０Ｌに移動
	BSR	PUTX2:8		; 移動したビット15〜8を出力
	MOV.B	R2L,R0L		; Ｒ２のビット7〜0をＲ０Ｌに移動し、
				; そのままPUTX2 になだれこんでビット7〜0を表示
;（２桁出力）
PUTX2	PUSH.W	R0		; Ｒ０保存
	SHLR.B	R0L		; この４行でビット7〜4をビット3〜0に移動
	SHLR.B	R0L		; 〃
	SHLR.B	R0L		; 〃
	SHLR.B	R0L		; 〃
	BSR	PUTX1:8		; 移動したビット7〜4を表示
	POP.W	R0		; Ｒ０復帰し、
				; そのままPUTX1 になだれこんでビット3〜0を表示
;（１桁出力）
PUTX1	AND.B	#H'0F,R0L	; 下位４ビットのみ取りだす
	CMP.B	#H'0A,R0L	; １０より
	BCS	PUTX11:8	; 　　小さくなければ
	ADD.B	#H'07,R0L	; 　　　　７を足す
PUTX11	ADD.B	#H'30,R0L	; H'30 を足す
	BRA	PUTCH:8		; １文字出力

　ＳＨ版の PUTXグループは、８桁出力ルーチンの中から４桁出力ルーチンを２回呼び、４桁出力ルーチンの中から２桁出力ルーチンを２回呼んで・・・というフラクタル的構造になっているのですが、Ｈ８版は８桁出力ルーチンの中から４桁出力ルーチンを１回呼んだ後、２回目の呼びだしはせずに直後に隣接する４桁出力ルーチンにそのままなだれ込みます。
　ＳＨ版が「フラクタル的」というならＨ８版は「レフレックス検波的」とでもいった感じでしょうか。最近はマイコンのプログラムも高級言語で組むのが普通になり、こういうトリッキーなアセンブラソースを書くことも無くなって寂しいかぎりです。

　今回はここまでとします。